Page backgrounds

You should append the "shell" to the end of a new PDF, capture it (which removes it from the document), then stamp it onto each new page using DrawCapturedPage(). No need for a hidden page.

This also keeps the file size small, since the captured page is a PDF template, and is stored only once in the PDF. For example, I have a PDF template with a letterhead graphic that is 19,630 bytes. Stamped onto each page of a seven-page report using DrawCapturedPage(), and writing text to each page, the total output file size is just 26,947 bytes.

Here's an example (vbscript) that reads a .txt file from a mainframe (with pagebreaks every nn lines), writes each page to a new PDF page, and stamps a letterhead graphic from another PDF file on each page.

Option Explicit

Const ForReading = 1
Const ForWriting = 2
Const Portrait      = "Letter"
Const Landscape = "Letter Landscape"

Dim QP, QuickPDFKey, srcFileName, destFileName, fso, src, lne, text, page, textSize
Dim fontID, docID
Dim templateFileName
Dim lines, maxLen

'-- Init iSedQuickPDF and FSO objects
Set QP = CreateObject("iSED.QuickPDF")
Set fso = CreateObject("Scripting.FileSystemObject")

'-- Set file names
QuickPDFKey             = WScript.Arguments(0)
srcFileName             = WScript.Arguments(1) '-- Text file to convert to PDF
destFileName            = WScript.Arguments(2) '-- Output PDF filename
templateFileName        = WScript.Arguments(3) '-- Letterhead PDF template filename

'-- Unlock the PDF library
Call QP.UnlockKey(QuickPDFKey)

'-- Open the text file for reading
Set src = fso.OpenTextFile(srcFileName, ForReading)

page     = 0
lines     = 0
maxLen     = 0
fontID     = 0

'-- Load PDF Template
docID = LoadTemplate(templateFileName)

Do Until src.AtEndOfStream
     
     '-- Read a line from text file
     lne = src.ReadLine & VbCr

     '-- If pagebreak is found
     If Left(lne,1) = Chr(12) Then
          '-- Write text to the template
          WritePage
          text = Mid(lne, 2)
          lines = 1
          maxLen = 0
     Else
          '-- Add the line to buffer
          text = text & lne
          lines = lines + 1
          If Len(lne) > maxLen Then
               maxLen = Len(lne)
          End If
     End If
Loop

'-- Write final page
WritePage

'-- Compress the file size
Call QP.CompressContent()

'-- Write to PDF file
Call QP.SaveToFile(destFileName)

Set fso = Nothing
Set src = Nothing
Set QP = Nothing

'-- Write the text to PDF page
'-- Use simple logic to set text and page size
Sub WritePage

     '-- Increment page counter
     page = page + 1

     '-- Create new PDF page
     If page > 1 Then
          Call QP.NewPage()
     End If

     '-- Set origin to top left corner
     Call QP.SetOrigin(1)

     '-- Select current page
     Call QP.SelectPage(page)

     '-- Set to portrait or landscape
     If maxLen > 100 Then
          Call QP.SetPageSize(Landscape)
     Else
          Call QP.SetPageSize(Portrait)
     End If

     '-- Draw the template onto current page
     Call QP.DrawCapturedPage(docID, 0, 0, QP.PageWidth(), QP.PageHeight())

     '-- Select Courier (fixed) font
     If fontID = 0 Then
          fontID = QP.AddStandardFont(0)
     End If
     Call QP.SelectFont(fontID)

     '-- Set text size
     If maxLen > 100 Then
          textSize = 8
     ElseIf lines > 80 Then
          textSize = 7
     ElseIf lines > 66 Or maxLen > 81 Then
          textSize = 8
     Else
          textSize = 10
     End If
     Call QP.SetTextSize(textSize)

     '-- Print info
     WScript.Echo "Page:             " & page
     WScript.Echo "Lines:            " & lines
     WScript.Echo "Max Line Length: " & maxLen
     WScript.Echo "Text Size:        " & textSize
     WScript.Echo ""

     '-- Draw report text onto template
     Call QP.DrawMultiLineText(72, 108, VbCr, text)

End Sub

'-- Load template PDF, capture first page, and return its ID
Function LoadTemplate(templateFileName)
     If QP.LoadFromFile(templateFileName) = 0 Then
          WScript.Echo("Could Not Load PDF Template: " & templateFileName)
          WScript.Quit(1)
     End If
     Call QP.SetOrigin(1)
     Call QP.NewPage()
     Call QP.SelectPage(1)
     LoadTemplate = QP.CapturePage(1)
End Function